Forum de Henri Chéli

paddle = GraphicsWindow.AddRectangle(120, 12)
ball = GraphicsWindow.AddEllipse(16, 16)

GraphicsWindow.BackgroundColor ="PaleGreen"
GraphicsWindow.FontSize = 14
GraphicsWindow.MouseMove = OnMouseMove

score = 0
PrintScore()
Sound.PlayBellRingAndWait()

x = 0
y = 0
deltaX = 1
deltaY = 2

RunLoop:
x = x + deltaX
y = y + deltaY

gw = GraphicsWindow.Width
gh = GraphicsWindow.Height
If (x >= gw - 16 Or x <= 0) Then
deltaX = -deltaX
EndIf
If (y <= 0) Then
deltaY = -deltaY
EndIf

padX = GraphicsWindow.GetLeftOfShape(paddle)
If (y = gh - 28 And x >= padX And x <= padX + 120) Then
Sound.PlayClick()
score = score + 10
PrintScore()
deltaY = -deltaY
EndIf

GraphicsWindow.MoveShape(ball, x, y)
Program.Delay(1)

If (y < gh) Then
Goto RunLoop
EndIf

GraphicsWindow.ShowMessage("Game Over ! Your score is: " + score, "Score")

Sub OnMouseMove
paddleX = GraphicsWindow.MouseX
GraphicsWindow.MoveShape(paddle, paddleX - 60, GraphicsWindow.Height - 12)
EndSub

Sub PrintScore
' Clear the score first and then draw the real score text
GraphicsWindow.BrushColor = "SkyBlue"
GraphicsWindow.FillRectangle(10, 10, 200, 20)
GraphicsWindow.BrushColor = "Black"
GraphicsWindow.DrawText(10, 10, "Score: " + score)
EndSub